mirror of
https://github.com/moonlight-stream/moonlight-common-c.git
synced 2025-07-01 07:15:39 +00:00
179970a0d5
- Allows static library compilation - Links to MBedTLS/OpenSSL based on build option - Limits visibility of some defines and headers
72 lines
2.4 KiB
CMake
72 lines
2.4 KiB
CMake
|
|
cmake_minimum_required(VERSION 3.1)
|
|
project(moonlight-common-c LANGUAGES C)
|
|
|
|
set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
|
|
|
|
option(USE_MBEDTLS "Use MbedTLS instead of OpenSSL" OFF)
|
|
|
|
SET(CMAKE_C_STANDARD 11)
|
|
|
|
aux_source_directory(src SRC_LIST)
|
|
aux_source_directory(enet SRC_LIST)
|
|
aux_source_directory(reedsolomon SRC_LIST)
|
|
|
|
# Build shared library by default, but allows user override
|
|
if (NOT DEFINED BUILD_SHARED_LIBS)
|
|
set(BUILD_SHARED_LIBS ON)
|
|
set(BUILD_SHARED_LIBS_OVERRIDE ON)
|
|
endif()
|
|
|
|
add_library(moonlight-common-c ${SRC_LIST})
|
|
|
|
if (BUILD_SHARED_LIBS_OVERRIDE)
|
|
unset(BUILD_SHARED_LIBS)
|
|
unset(BUILD_SHARED_LIBS_OVERRIDE)
|
|
endif()
|
|
|
|
if(MSVC)
|
|
target_compile_options(moonlight-common-c PRIVATE /W4 /wd4100 /wd4232)
|
|
target_compile_definitions(moonlight-common-c PRIVATE -D_CRT_SECURE_NO_WARNINGS=1 -D_CRT_NONSTDC_NO_DEPRECATE=1)
|
|
target_link_libraries(moonlight-common-c PRIVATE ws2_32.lib qwave.lib winmm.lib)
|
|
else()
|
|
target_compile_options(moonlight-common-c PRIVATE -Wall -Wextra -Wno-unused-parameter -Werror)
|
|
endif()
|
|
|
|
if (USE_MBEDTLS)
|
|
target_compile_definitions(moonlight-common-c PRIVATE USE_MBEDTLS)
|
|
find_package(MbedTLS QUIET)
|
|
if (MBEDTLS_FOUND)
|
|
target_link_libraries(moonlight-common-c PRIVATE ${MBEDCRYPTO_LIBRARY})
|
|
target_include_directories(moonlight-common-c SYSTEM PRIVATE ${MBEDTLS_INCLUDE_DIRS})
|
|
else()
|
|
# For sub project added via CMake
|
|
target_link_libraries(moonlight-common-c PRIVATE mbedtls)
|
|
endif()
|
|
else()
|
|
find_package(OpenSSL 1.0.2 REQUIRED)
|
|
target_link_libraries(moonlight-common-c PRIVATE ${OPENSSL_CRYPTO_LIBRARY})
|
|
target_include_directories(moonlight-common-c SYSTEM PRIVATE ${OPENSSL_INCLUDE_DIR})
|
|
endif()
|
|
|
|
string(TOUPPER "x${CMAKE_BUILD_TYPE}" BUILD_TYPE)
|
|
if("${BUILD_TYPE}" STREQUAL "XDEBUG")
|
|
target_compile_definitions(moonlight-common-c PRIVATE LC_DEBUG)
|
|
else()
|
|
target_compile_definitions(moonlight-common-c PRIVATE NDEBUG)
|
|
|
|
# Avoid false "maybe uninitialized" warning generated by old GCC versions
|
|
# when building with -O2
|
|
if(CMAKE_C_COMPILER_ID STREQUAL "GNU")
|
|
target_compile_options(moonlight-common-c PRIVATE -Wno-maybe-uninitialized)
|
|
endif()
|
|
endif()
|
|
|
|
target_include_directories(moonlight-common-c SYSTEM PUBLIC src)
|
|
|
|
target_include_directories(moonlight-common-c PRIVATE
|
|
${CMAKE_CURRENT_SOURCE_DIR}/enet/include
|
|
${CMAKE_CURRENT_SOURCE_DIR}/reedsolomon
|
|
)
|
|
|
|
target_compile_definitions(moonlight-common-c PRIVATE HAS_SOCKLEN_T) |