moonlight-android/app/build.gradle

import com.android.builder.model.ProductFlavor
import org.apache.tools.ant.taskdefs.condition.Os

apply plugin: 'com.android.application'

android {
    compileSdkVersion 27
    buildToolsVersion '27.0.0'

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion 27

        versionName "5.2.1"
        versionCode = 132
    }

    flavorDimensions "root"

    productFlavors {
        root {
            // Android O has native mouse capture, so don't show the rooted
            // version to devices running O on the Play Store.
            maxSdkVersion 25

            applicationId "com.limelight.root"
            ndk {
                abiFilters "armeabi-v7a", "arm64-v8a", "x86", "x86_64", "mips", "mips64"
            }

            dimension "root"
        }

        nonRoot {
            applicationId "com.limelight"
            ndk {
                abiFilters "armeabi-v7a", "arm64-v8a", "x86", "x86_64", "mips", "mips64"
            }

            dimension "root"
        }
    }

    lintOptions {
        disable 'MissingTranslation'
    }

    buildTypes {
        debug {
            applicationIdSuffix ".debug"
        }
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt')
        }
    }

    externalNativeBuild {
        ndkBuild {
            path "src/main/jni/Android.mk"
        }
    }
}

dependencies {
    implementation 'org.bouncycastle:bcprov-jdk15on:1.57'
    implementation 'org.bouncycastle:bcpkix-jdk15on:1.57'
    implementation files('libs/jcodec-0.1.9-patched.jar')

    implementation project(':moonlight-common')
}