plugins {
    id 'java'
    id 'io.freefair.lombok' version '5.2.1'
    id "com.github.johnrengelman.shadow" version "7.0.0"
}

group 'com.volmit.iris'
version '1.4.1'
def apiVersion = '1.17'
def name = 'Iris'
def main = 'com.volmit.iris.Iris'

// ADD YOURSELF AS A NEW LINE IF YOU WANT YOUR OWN BUILD TASK GENERATED
// ==============================================================
registerCustomOutputTask('Cyberpwn', 'C://Users/cyberpwn/Documents/development/server/plugins');
registerCustomOutputTask('ArcaneArts', 'C://Users/arcane/Documents/development/server/plugins');
// ==============================================================

def registerCustomOutputTask(name, path) {
    tasks.register('build' + name, Copy) {
        group('development')
        outputs.upToDateWhen{false}
        dependsOn ':shadowJar'
        from(file('build/libs/Iris-' + version + '-all.jar'))
        into(file(path))
        rename { String fileName ->
            fileName.replace('Iris-' + version + '-all.jar', "Iris.jar")
        }
    }
}

processResources {
    filesMatching('**/plugin.yml') {
        expand(
            'name': name.toString(),
            'version': version.toString(),
            'main': main.toString(),
            'apiversion': apiVersion.toString()
        )
    }
}

repositories {
    maven {
        allowInsecureProtocol true
        url "http://archive.arcane.art/repository/arcane"
    }
    mavenLocal()
}

shadowJar
{
    minimize()
    dependencies {
        include(dependency('com.github.ben-manes.caffeine:caffeine:2.8.5'))
        include(dependency('org.zeroturnaround:zt-zip:1.14'))
        include(dependency('io.papermc:paperlib:1.0.5'))
    }
}

dependencies {
    compileOnly 'org.projectlombok:lombok:1.18.20'
    annotationProcessor 'org.projectlombok:lombok:1.18.20'

    // Shade
    implementation 'com.github.ben-manes.caffeine:caffeine:3.0.2'
    implementation 'org.zeroturnaround:zt-zip:1.14'
    implementation 'io.papermc:paperlib:1.0.5'

    // Provided
    implementation 'org.spigotmc:spigot-api:1.17-R0.1-SNAPSHOT'
    implementation 'org.bukkit.craftbukkit:1.17:1.17'
    implementation 'com.bergerkiller.bukkit:BKCommonLib:1.16.4-v2'
    implementation 'com.sk89q.worldedit:worldedit-bukkit:7.2.0-SNAPSHOT'
    implementation 'io.lumine.xikage:MythicMobs:4.9.1'
    implementation 'com.google.code.gson:gson:2.8.5'
}