String apiVersion = providers.gradleProperty('minecraftVersion').get()
def mainClass = 'art.arcane.iris.Iris'
def bootstrapperClass = 'art.arcane.iris.IrisBootstrap'

String volmLibCoordinate = providers.gradleProperty('volmLibCoordinate')
    .orElse('com.github.VolmitSoftware:VolmLib:cdf7e8bb880199734dacd386a6616bda799fcde1')
    .get()

dependencies {
    compileOnly(project(':core'))
    compileOnly(volmLibCoordinate) {
        transitive = false
    }
    compileOnly(libs.paper.api)
    testImplementation('junit:junit:4.13.2')
    testImplementation(libs.paper.api)
    testImplementation(libs.bstats)
    testImplementation(libs.sentry)
    testImplementation(project(':core'))
    testImplementation(volmLibCoordinate) {
        transitive = false
    }
    compileOnly(libs.placeholderApi)
    compileOnly(libs.multiverseCore)
}

tasks.named('processResources').configure {
    def pluginProperties = [
        name      : rootProject.name,
        version   : rootProject.version,
        apiVersion: apiVersion,
        main      : mainClass,
        bootstrapper: bootstrapperClass,
    ]
    inputs.properties(pluginProperties)
    filesMatching(['**/paper-plugin.yml', '**/plugin.yml']) {
        expand(pluginProperties)
    }
}

tasks.named('jar', Jar).configure {
    archiveBaseName.set('iris-bukkit-plugin')
}