String apiVersion = providers.gradleProperty('minecraftVersion').get()
def mainClass = 'art.arcane.iris.Iris'
def bootstrapperClass = 'art.arcane.iris.IrisBootstrap'

String volmLibCoordinate = providers.gradleProperty('volmLibCoordinate')
    .orElse('com.github.VolmitSoftware:VolmLib:4c38988b344792a79f925f57f8a675bc85fc1bed')
    .get()

dependencies {
    compileOnly(project(':core'))
    compileOnly(libs.lombok)
    annotationProcessor(libs.lombok)
    compileOnly(volmLibCoordinate) {
        transitive = false
    }
    compileOnly(libs.paper.api)
    testImplementation('junit:junit:4.13.2')
    testImplementation(libs.paper.api)
    testImplementation(libs.bstats)
    testImplementation(libs.sentry)
    testImplementation(project(':core'))
    testImplementation(volmLibCoordinate) {
        transitive = false
    }
    compileOnly(libs.placeholderApi)
}

tasks.named('processResources').configure {
    def pluginProperties = [
        name      : rootProject.name,
        version   : rootProject.version,
        apiVersion: apiVersion,
        main      : mainClass,
        bootstrapper: bootstrapperClass,
    ]
    inputs.properties(pluginProperties)
    filesMatching(['**/paper-plugin.yml', '**/plugin.yml']) {
        expand(pluginProperties)
    }
}

tasks.named('jar', Jar).configure {
    archiveBaseName.set('iris-bukkit-plugin')
}

tasks.named('test').configure {
    systemProperty('iris.commandFindSource', file('src/main/java/art/arcane/iris/core/commands/CommandFind.java').absolutePath)
    systemProperty('iris.commandStructureSource', file('src/main/java/art/arcane/iris/core/commands/CommandStructure.java').absolutePath)
}