switch to vcpkg+cmake, add debian build to workflows

using lionkor's template (MIT licensed)

This is a combination of 64 commits.

cmake/CompilerWarnings.cmake

@@ -0,0 +1,115 @@
+# from here:
+#
+# https://github.com/lefticus/cppbestpractices/blob/master/02-Use_the_Tools_Available.md
+# Courtesy of Jason Turner
+# License here: https://github.com/cpp-best-practices/cppbestpractices/blob/master/LICENSE
+# 
+# This version has been modified by the owners of the current respository.
+# Modifications have mostly been marked with "modified" or similar, though this is not 
+# strictly required.
+
+function(set_project_warnings project_name)
+    set(MSVC_WARNINGS
+            /W4         # Baseline reasonable warnings
+            /w14242 # 'identifier': conversion from 'type1' to 'type1', possible loss
+                            # of data
+            /w14254 # 'operator': conversion from 'type1:field_bits' to
+                            # 'type2:field_bits', possible loss of data
+            /w14263 # 'function': member function does not override any base class
+                            # virtual member function
+            /w14265 # 'classname': class has virtual functions, but destructor is not
+                            # virtual instances of this class may not be destructed correctly
+            /w14287 # 'operator': unsigned/negative constant mismatch
+            /we4289 # nonstandard extension used: 'variable': loop control variable
+                            # declared in the for-loop is used outside the for-loop scope
+            /w14296 # 'operator': expression is always 'boolean_value'
+            /w14311 # 'variable': pointer truncation from 'type1' to 'type2'
+            /w14545 # expression before comma evaluates to a function which is missing
+                            # an argument list
+            /w14546 # function call before comma missing argument list
+            /w14547 # 'operator': operator before comma has no effect; expected
+                            # operator with side-effect
+            /w14549 # 'operator': operator before comma has no effect; did you intend
+                            # 'operator'?
+            /w14555 # expression has no effect; expected expression with side- effect
+            /w14619 # pragma warning: there is no warning number 'number'
+            /w14640 # Enable warning on thread un-safe static member initialization
+            /w14826 # Conversion from 'type1' to 'type_2' is sign-extended. This may
+                            # cause unexpected runtime behavior.
+            /w14905 # wide string literal cast to 'LPSTR'
+            /w14906 # string literal cast to 'LPWSTR'
+            /w14928 # illegal copy-initialization; more than one user-defined
+                            # conversion has been implicitly applied
+            /permissive- # standards conformance mode for MSVC compiler.
+    )
+
+    set(CLANG_WARNINGS
+            -Wall
+            -Wextra    # reasonable and standard
+            -Wshadow # warn the user if a variable declaration shadows one from a
+                             # parent context
+            -Wnon-virtual-dtor # warn the user if a class with virtual functions has a
+                                                 # non-virtual destructor. This helps catch hard to
+                                                 # track down memory errors
+            -Wold-style-cast # warn for c-style casts
+            -Wcast-align         # warn for potential performance problem casts
+            -Wunused                 # warn on anything being unused
+            -Woverloaded-virtual # warn if you overload (not override) a virtual
+                                                     # function
+            -Wpedantic     # warn if non-standard C++ is used
+            -Wconversion # warn on type conversions that may lose data
+            -Wsign-conversion    # warn on sign conversions
+            -Wnull-dereference # warn if a null dereference is detected
+            -Wdouble-promotion # warn if float is implicit promoted to double
+            -Wformat=2 # warn on security issues around functions that format output
+                                 # (ie printf)
+            # modified; added more errors / warnings
+            # some have been set to be errors, but the option _WARNINGS_AS_ERRORS
+            # (see below) should still be used in strict pipelines.
+            -Werror=uninitialized
+            -Werror=float-equal
+            -Werror=write-strings
+            -Werror=strict-aliasing -fstrict-aliasing
+            -Werror=missing-declarations
+            -Werror=missing-field-initializers
+            -Werror=ctor-dtor-privacy
+            -Werror=switch-enum
+            -Wswitch-default
+            -Werror=unused-result
+            -Werror=implicit-fallthrough
+            -Werror=return-type
+            -Wmissing-include-dirs
+    )
+
+    if (${PROJECT_NAME}_WARNINGS_AS_ERRORS)
+        set(CLANG_WARNINGS ${CLANG_WARNINGS} -Werror)
+        set(MSVC_WARNINGS ${MSVC_WARNINGS} /WX)
+    endif()
+
+    set(GCC_WARNINGS
+            ${CLANG_WARNINGS}
+            -Wmisleading-indentation # warn if indentation implies blocks where blocks
+                                                             # do not exist
+            -Wduplicated-cond # warn if if / else chain has duplicated conditions
+            -Wduplicated-branches # warn if if / else branches have duplicated code
+            -Wlogical-op     # warn about logical operations being used where bitwise were
+                                         # probably wanted
+            # -Wuseless-cast # warn if you perform a cast to the same type (modified: removed)
+    )
+
+    if(MSVC)
+        set(PRJ_WARNINGS ${MSVC_WARNINGS})
+    elseif(CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
+        set(PRJ_WARNINGS ${CLANG_WARNINGS})
+    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
+        set(PRJ_WARNINGS ${GCC_WARNINGS})
+    else()
+        message(AUTHOR_WARNING "No compiler warnings set for '${CMAKE_CXX_COMPILER_ID}' compiler.")
+    endif()
+
+    target_compile_options(${project_name} PUBLIC ${PRJ_WARNINGS})
+
+    if(NOT TARGET ${project_name})
+        message(AUTHOR_WARNING "${project_name} is not a target, thus no compiler warning were added.")
+    endif()
+endfunction()

cmake/Git.cmake

@@ -0,0 +1,21 @@
+find_package(Git)
+if(${PROJECT_NAME}_CHECKOUT_GIT_SUBMODULES)
+    if(Git_FOUND)
+        message(STATUS "Git found, submodule update and init")
+        execute_process(COMMAND ${GIT_EXECUTABLE} submodule update --init --recursive
+                        WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+                        RESULT_VARIABLE GIT_SUBMOD_RESULT)
+        if(NOT GIT_SUBMOD_RESULT EQUAL "0")
+            message(SEND_ERROR "git submodule update --init --recursive failed with ${GIT_SUBMOD_RESULT}, please checkout submodules. This may result in missing dependencies.")
+        endif()
+    else()
+        message(SEND_ERROR "git required for checking out submodules, but not found. Submodules will not be checked out - this may result in missing dependencies.")
+    endif()
+endif()
+
+if(Git_FOUND)
+
+else()
+    message(STATUS "Git not found - the version will not include a git hash.")
+    set(PRJ_GIT_HASH "unknown")
+endif()

cmake/StandardSettings.cmake

@@ -0,0 +1,44 @@
+# Modified, original version from https://github.com/filipdutescu/modern-cpp-template (Unlicense)
+
+option(${PROJECT_NAME}_WARNINGS_AS_ERRORS "Treat compiler warnings as errors." OFF)
+option(${PROJECT_NAME}_CHECKOUT_GIT_SUBMODULES "If git is found, initialize all submodules." ON)
+option(${PROJECT_NAME}_ENABLE_UNIT_TESTING "Enable unit tests for the projects (from the `test` subfolder)." ON)
+option(${PROJECT_NAME}_ENABLE_CLANG_TIDY "Enable static analysis with Clang-Tidy." OFF)
+option(${PROJECT_NAME}_ENABLE_CPPCHECK "Enable static analysis with Cppcheck." OFF)
+# TODO Implement code coverage
+# option(${PROJECT_NAME}_ENABLE_CODE_COVERAGE "Enable code coverage through GCC." OFF)
+option(${PROJECT_NAME}_ENABLE_DOXYGEN "Enable Doxygen documentation builds of source." OFF)
+
+# Generate compile_commands.json for clang based tools
+set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+
+# Export all symbols when building a shared library
+if(BUILD_SHARED_LIBS)
+    set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS OFF)
+    set(CMAKE_CXX_VISIBILITY_PRESET hidden)
+    set(CMAKE_VISIBILITY_INLINES_HIDDEN 1)
+endif()
+
+option(${PROJECT_NAME}_ENABLE_LTO "Enable Interprocedural Optimization, aka Link Time Optimization (LTO)." OFF)
+if(${PROJECT_NAME}_ENABLE_LTO)
+    include(CheckIPOSupported)
+    check_ipo_supported(RESULT result OUTPUT output)
+    if(result)
+        set(CMAKE_INTERPROCEDURAL_OPTIMIZATION TRUE)
+    else()
+        message(SEND_ERROR "IPO is not supported: ${output}.")
+    endif()
+endif()
+
+option(${PROJECT_NAME}_ENABLE_CCACHE "Enable the usage of Ccache, in order to speed up rebuild times." ON)
+find_program(CCACHE_FOUND ccache)
+if(CCACHE_FOUND)
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
+    set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
+endif()
+
+option(${PROJECT_NAME}_ENABLE_SANITIZER "Enable sanitizer to detect memory errors, undefined behavior, etc. (slows down the executable)." OFF)
+if(${PROJECT_NAME}_ENABLE_SANITIZER)
+    add_compile_options(-fsanitize=address,undefined)
+    add_link_options(-fsanitize=address,undefined)
+endif()

cmake/StaticAnalyzers.cmake

@@ -0,0 +1,20 @@
+if(${PROJECT_NAME}_ENABLE_CLANG_TIDY)
+  find_program(CLANGTIDY clang-tidy)
+  if(CLANGTIDY)
+    set(CMAKE_CXX_CLANG_TIDY ${CLANGTIDY} -extra-arg=-Wno-unknown-warning-option)
+    message("Clang-Tidy finished setting up.")
+  else()
+    message(SEND_ERROR "Clang-Tidy requested but executable not found.")
+  endif()
+endif()
+
+if(${PROJECT_NAME}_ENABLE_CPPCHECK)
+  find_program(CPPCHECK cppcheck)
+  if(CPPCHECK)
+    set(CMAKE_CXX_CPPCHECK ${CPPCHECK} --suppress=missingInclude --enable=all
+                           --inline-suppr --inconclusive)
+    message("Cppcheck finished setting up.")
+  else()
+    message(SEND_ERROR "Cppcheck requested but executable not found.")
+  endif()
+endif()

cmake/Vcpkg.cmake

@@ -0,0 +1,17 @@
+if(NOT DEFINED CMAKE_TOOLCHAIN_FILE)
+    if(NOT EXISTS ${CMAKE_SOURCE_DIR}/vcpkg/scripts/buildsystems/vcpkg.cmake)
+        find_package(Git)
+        if(Git_FOUND)
+            execute_process(COMMAND ${GIT_EXECUTABLE} submodule update --init --recursive vcpkg
+                            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+                            RESULT_VARIABLE GIT_SUBMOD_RESULT)
+            if(NOT GIT_SUBMOD_RESULT EQUAL "0")
+                message(SEND_ERROR "Checking out vcpkg in source tree failed with ${GIT_SUBMOD_RESULT}.")
+            endif()
+        else()
+            message(FATAL_ERROR "Could not find git or vcpkg.cmake. Please either, install git and re-run cmake (or run `git submodule update --init --recursive`), or install vcpkg and add `-DCMAKE_TOOLCHAIN_FILE=<path-to-vcpkg>/scripts/buildsystems/vcpkg.cmake` to your cmake invocation. Please try again after making those changes.")
+        endif()
+    endif()
+    set(CMAKE_TOOLCHAIN_FILE ${CMAKE_SOURCE_DIR}/vcpkg/scripts/buildsystems/vcpkg.cmake)
+endif()
+