BeamMP-Launcher/cmake/CompilerWarnings.cmake

# from here:
#
# https://github.com/lefticus/cppbestpractices/blob/master/02-Use_the_Tools_Available.md
# Courtesy of Jason Turner
# License here: https://github.com/cpp-best-practices/cppbestpractices/blob/master/LICENSE
# 
# This version has been modified by the owners of the current respository.
# Modifications have mostly been marked with "modified" or similar, though this is not 
# strictly required.

function(set_project_warnings project_name)
    set(MSVC_WARNINGS
            /W4         # Baseline reasonable warnings
            /w14242 # 'identifier': conversion from 'type1' to 'type1', possible loss
                            # of data
            /w14254 # 'operator': conversion from 'type1:field_bits' to
                            # 'type2:field_bits', possible loss of data
            /w14263 # 'function': member function does not override any base class
                            # virtual member function
            /w14265 # 'classname': class has virtual functions, but destructor is not
                            # virtual instances of this class may not be destructed correctly
            /w14287 # 'operator': unsigned/negative constant mismatch
            /we4289 # nonstandard extension used: 'variable': loop control variable
                            # declared in the for-loop is used outside the for-loop scope
            /w14296 # 'operator': expression is always 'boolean_value'
            /w14311 # 'variable': pointer truncation from 'type1' to 'type2'
            /w14545 # expression before comma evaluates to a function which is missing
                            # an argument list
            /w14546 # function call before comma missing argument list
            /w14547 # 'operator': operator before comma has no effect; expected
                            # operator with side-effect
            /w14549 # 'operator': operator before comma has no effect; did you intend
                            # 'operator'?
            /w14555 # expression has no effect; expected expression with side- effect
            /w14619 # pragma warning: there is no warning number 'number'
            /w14640 # Enable warning on thread un-safe static member initialization
            /w14826 # Conversion from 'type1' to 'type_2' is sign-extended. This may
                            # cause unexpected runtime behavior.
            /w14905 # wide string literal cast to 'LPSTR'
            /w14906 # string literal cast to 'LPWSTR'
            /w14928 # illegal copy-initialization; more than one user-defined
                            # conversion has been implicitly applied
            /permissive- # standards conformance mode for MSVC compiler.
    )

    set(CLANG_WARNINGS
            -Wall
            -Wextra    # reasonable and standard
            -Wshadow # warn the user if a variable declaration shadows one from a
                             # parent context
            -Wnon-virtual-dtor # warn the user if a class with virtual functions has a
                                                 # non-virtual destructor. This helps catch hard to
                                                 # track down memory errors
            -Wold-style-cast # warn for c-style casts
            -Wcast-align         # warn for potential performance problem casts
            -Wunused                 # warn on anything being unused
            -Woverloaded-virtual # warn if you overload (not override) a virtual
                                                     # function
            -Wpedantic     # warn if non-standard C++ is used
            -Wconversion # warn on type conversions that may lose data
            -Wsign-conversion    # warn on sign conversions
            -Wnull-dereference # warn if a null dereference is detected
            -Wdouble-promotion # warn if float is implicit promoted to double
            -Wformat=2 # warn on security issues around functions that format output
                                 # (ie printf)
            # modified; added more errors / warnings
            # some have been set to be errors, but the option _WARNINGS_AS_ERRORS
            # (see below) should still be used in strict pipelines.
            -Werror=uninitialized
            -Werror=float-equal
            -Werror=write-strings
            -Werror=strict-aliasing -fstrict-aliasing
            -Werror=missing-declarations
            -Werror=ctor-dtor-privacy
            -Wunused-result
            -Werror=implicit-fallthrough
            -Wmissing-include-dirs
    )

    if (${PROJECT_NAME}_WARNINGS_AS_ERRORS)
        set(CLANG_WARNINGS ${CLANG_WARNINGS} -Werror)
        set(MSVC_WARNINGS ${MSVC_WARNINGS} /WX)
    endif()

    set(GCC_WARNINGS
            ${CLANG_WARNINGS}
            -Wmisleading-indentation # warn if indentation implies blocks where blocks
                                                             # do not exist
            -Wduplicated-cond # warn if if / else chain has duplicated conditions
            -Wduplicated-branches # warn if if / else branches have duplicated code
            -Wlogical-op     # warn about logical operations being used where bitwise were
                                         # probably wanted
            # -Wuseless-cast # warn if you perform a cast to the same type (modified: removed)
    )

    if(MSVC)
        set(PRJ_WARNINGS ${MSVC_WARNINGS})
    elseif(CMAKE_CXX_COMPILER_ID MATCHES ".*Clang")
        set(PRJ_WARNINGS ${CLANG_WARNINGS})
    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
        set(PRJ_WARNINGS ${GCC_WARNINGS})
    else()
        message(AUTHOR_WARNING "No compiler warnings set for '${CMAKE_CXX_COMPILER_ID}' compiler.")
    endif()

    target_compile_options(${project_name} PUBLIC ${PRJ_WARNINGS})

    if(NOT TARGET ${project_name})
        message(AUTHOR_WARNING "${project_name} is not a target, thus no compiler warning were added.")
    endif()
endfunction()